kdenlive to mmg/mkv and bombono

<?xml version="1.0"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <!-- Convert kdenlive guide markers into Bombono parts
      that can be pasted into bombono xml project files.
 
      This works with kdenlive 16.12.
      Earlier versions of kdenlive were different;
      they had mlt/kdenlivedoc/guides/guide tags
      which are not generated anymore
 -->
 <xsl:output indent="yes"/>
 
 <xsl:template match="/">
  <Parts>
    <xsl:for-each select="mlt/playlist/property[substring(@name, 0, 16) = 'kdenlive:guide.']">
      <!-- we need to sort manually, they can appear in any order -->
      <xsl:sort data-type="number" select="translate(substring(@name, 16),',','.')"/>
 
      <xsl:variable name="timeorig" select="substring(@name, 16)"/>
      <!-- support german files with comma as decimal separator-->
      <xsl:variable name="time" select="translate($timeorig,',','.')"/>
 
      <Part>
        <xsl:attribute name="Name"><xsl:value-of select="."/></xsl:attribute>
        <xsl:value-of select="$time"/>
      </Part>
    </xsl:for-each>
  </Parts>
 </xsl:template>
 
</xsl:stylesheet> 

<?xml version="1.0"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <!-- Convert kdenlive guide markers into MKV chapters.
 
      this works with kdenlive 17.07.70.
      Earlier versions were different.
 -->
 <xsl:output indent="yes"/>
 
 <xsl:template match="/">
  <Chapters>
   <EditionEntry>
      <xsl:for-each select="mlt/playlist/property[substring(@name, 0, 16) = 'kdenlive:guide.']">
        <!-- we need to sort manually, they can appear in any order -->
        <xsl:sort data-type="number" select="substring-before(concat(translate(substring(@name, 16),'.',''),','),',')"/>
 
        <xsl:variable name="timeorig" select="substring(@name, 16)"/>
        <!-- remove sub-seconds "2.652,56" -->
        <xsl:variable name="time"
                      select="substring-before(
                                concat(
                                  translate(
                                    substring(@name, 16),
                                    '.', 
                                    ''
                                  ),
                                  ','
                                ),
                                ','
                              )"/>
 
        <xsl:variable name="seconds" select="$time mod 60" />
        <xsl:variable name="minutes" select="floor($time div 60) mod 60" />
        <xsl:variable name="hours" select="floor(($time div 60) div 60)" />
        <!-- hh:mm:ss.msec -->
        <xsl:variable name="timecode">
          <xsl:value-of select="format-number($hours, '00')"/>
          <xsl:text>:</xsl:text>
          <xsl:value-of select="format-number($minutes, '00')"/>
          <xsl:text>:</xsl:text>
          <xsl:value-of select="format-number($seconds, '00.000')"/>
        </xsl:variable>
           
        <ChapterAtom>
          <ChapterDisplay>
            <ChapterString>
              <xsl:if test=".!='Hilfslinie'">
                <xsl:value-of select="."/>
              </xsl:if>
            </ChapterString>
            <ChapterLanguage>ger</ChapterLanguage>
          </ChapterDisplay>
          <ChapterFlagHidden>
            <xsl:choose>
              <xsl:when test=".='Hilfslinie'">1</xsl:when>
              <xsl:otherwise>0</xsl:otherwise>
            </xsl:choose>
          </ChapterFlagHidden>
          <ChapterFlagEnabled>1</ChapterFlagEnabled>
          <ChapterTimeStart>
            <xsl:value-of select="$timecode"/>
          </ChapterTimeStart>
        </ChapterAtom>
      </xsl:for-each>
 
   </EditionEntry>
  </Chapters>
 </xsl:template>
 
</xsl:stylesheet>